CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.1 FATAL_ERROR)
   2 project(onak VERSION 0.6.0 LANGUAGES C)
   3
   4 include(CheckSymbolExists)
   5 include(FindPkgConfig)
   6 include(GNUInstallDirs)
   7 include(TestBigEndian)
   8 # Fall back for earlier versions of CMake which lack RUNSTATEDIR
   9 if ("x${CMAKE_INSTALL_FULL_RUNSTATEDIR}" STREQUAL "x")
  10         set(CMAKE_INSTALL_FULL_RUNSTATEDIR
  11                 ${CMAKE_INSTALL_FULL_LOCALSTATEDIR}/run)
  12 endif()
  13
  14 list(APPEND CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
  15
  16 # Configuration options from the user
  17 set(DBTYPE "dynamic" CACHE STRING
  18         "Configure the default database backend to use" )
  19 option(KEYD
  20         "Enable the key daemon to handle communication with the key database"
  21         ON)
  22
  23 set(CMAKE_POSITION_INDEPENDENT_CODE ON)
  24 TEST_BIG_ENDIAN(WORDS_BIGENDIAN)
  25
  26 # Pick up a git based version number for development builds
  27 find_package(Git)
  28 if (GIT_FOUND AND EXISTS "${CMAKE_SOURCE_DIR}/.git")
  29         EXECUTE_PROCESS(COMMAND ${GIT_EXECUTABLE} describe --tags --dirty
  30                 OUTPUT_VARIABLE GIT_VERSION
  31                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  32         string(REPLACE "onak-" "" VERSION ${GIT_VERSION})
  33 else()
  34         set(VERSION ${PROJECT_VERSION})
  35 endif()
  36
  37 # Core objects
  38 add_library(libonak STATIC armor.c charfuncs.c cleankey.c cleanup.c decodekey.c
  39         getcgi.c hash.c keyarray.c keyid.c keyindex.c ll.c log.c marshal.c
  40         mem.c merge.c onak-conf.c parsekey.c photoid.c rsa.c sigcheck.c sendsync.c
  41         sha1x.c wordlist.c)
  42 set(LIBONAK_LIBRARIES "")
  43
  44 # Ideally use Nettle, fall back to our own md5/sha1 routines otherwise
  45 pkg_check_modules(NETTLE nettle)
  46 if (NETTLE_FOUND)
  47         set(HAVE_NETTLE true)
  48         target_include_directories(libonak SYSTEM PUBLIC ${NETTLE_INCLUDE_DIRS})
  49         LIST(APPEND LIBONAK_LIBRARIES ${NETTLE_LIBRARIES})
  50 else()
  51         target_sources(libonak PRIVATE md5.c sha1.c)
  52 endif()
  53
  54 # We need libhogweed and libgmp to be able to do more than hash calculations
  55 pkg_check_modules(HOGWEED hogweed)
  56 if (HOGWEED_FOUND)
  57         find_package(GMP)
  58 endif()
  59 if (GMP_FOUND)
  60         set(HAVE_CRYPTO true)
  61         target_include_directories(libonak SYSTEM PUBLIC
  62                         ${GMP_INCLUDE_DIRS} ${HOGWEED_INCLUDE_DIRS})
  63         LIST(APPEND LIBONAK_LIBRARIES ${GMP_LIBRARY} ${HOGWEED_LIBRARIES})
  64
  65         set(CMAKE_REQUIRED_INCLUDES ${NETTLE_INCLUDE_DIRS})
  66         set(CMAKE_REQUIRED_LIBRARIES ${NETTLE_LIBRARIES} ${HOGWEED_LIBRARIES})
  67         # API change in later version of Nettle
  68         CHECK_SYMBOL_EXISTS(nettle_get_secp_256r1 "nettle/ecc-curve.h" HAVE_NETTLE_GET_SECP_256R1)
  69         CHECK_SYMBOL_EXISTS(nettle_get_secp_384r1 "nettle/ecc-curve.h" HAVE_NETTLE_GET_SECP_384R1)
  70         CHECK_SYMBOL_EXISTS(nettle_get_secp_521r1 "nettle/ecc-curve.h" HAVE_NETTLE_GET_SECP_521R1)
  71 endif()
  72
  73 # Build files that have substitutions in them
  74 include_directories(${CMAKE_BINARY_DIR} ${CMAKE_SOURCE_DIR})
  75 configure_file("${CMAKE_SOURCE_DIR}/build-config.h.in"
  76         "${CMAKE_BINARY_DIR}/build-config.h" @ONLY)
  77
  78 configure_file("${CMAKE_SOURCE_DIR}/onak.ini.in"
  79         "${CMAKE_BINARY_DIR}/onak.ini" @ONLY)
  80 install(FILES ${CMAKE_BINARY_DIR}/onak.ini
  81         DESTINATION ${CMAKE_INSTALL_SYSCONFDIR})
  82
  83 configure_file("${CMAKE_SOURCE_DIR}/onak-mail.pl.in"
  84         "${CMAKE_BINARY_DIR}/onak-mail.pl" @ONLY)
  85 install(PROGRAMS ${CMAKE_BINARY_DIR}/onak-mail.pl
  86         DESTINATION ${CMAKE_INSTALL_LIBDIR}/onak/)
  87 install(FILES onak-mail.pl.8 DESTINATION ${CMAKE_INSTALL_MANDIR}/man8/)
  88
  89 # Key database backends
  90 add_subdirectory(keydb)
  91
  92 # Now we have the DB type confirmed we can tidy up the libonak options
  93
  94 if (DBTYPE STREQUAL "dynamic")
  95         LIST(APPEND LIBONAK_LIBRARIES "dl")
  96 else()
  97         list (FIND BACKENDS ${DBTYPE} _index)
  98         if (${_index} LESS 0)
  99                 message(FATAL_ERROR "${DBTYPE} is not a supported DB backend.")
 100         endif()
 101
 102         LIST(APPEND LIBONAK_LIBRARIES ${BACKEND_${DBTYPE}_LIBS})
 103 endif()
 104
 105 # For onak-conf.o compilation
 106 target_compile_definitions(libonak PRIVATE
 107         CONFIGDIR="${CMAKE_INSTALL_FULL_SYSCONFDIR}"
 108         DBINIT=keydb_${DBTYPE}_init)
 109
 110 # DB Backend related options are known, so finish off libonak configuration
 111 target_sources(libonak PRIVATE keydb/keydb_${DBTYPE}.c)
 112 target_link_libraries(libonak ${LIBONAK_LIBRARIES})
 113
 114 # CGI directory
 115 add_subdirectory(cgi)
 116
 117 # Executables start here
 118
 119 # Swiss Army tool
 120 add_executable(onak onak.c)
 121 target_link_libraries(onak libonak)
 122
 123 # Tools that operate on the key DB
 124 add_executable(maxpath maxpath.c stats.c)
 125 target_link_libraries(maxpath libonak)
 126 add_executable(sixdegrees sixdegrees.c stats.c)
 127 target_link_libraries(sixdegrees libonak)
 128 add_executable(wotsap wotsap.c)
 129 target_link_libraries(wotsap libonak)
 130
 131 # Stand alone tools
 132 add_executable(splitkeys splitkeys.c)
 133 target_link_libraries(splitkeys libonak)
 134 add_executable(stripkey stripkey.c)
 135 target_link_libraries(stripkey libonak)
 136
 137 install(TARGETS onak splitkeys RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 138 install(FILES onak.1 splitkeys.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1/)
 139
 140 # Basic unit tests
 141 enable_testing()
 142 add_test(NAME syntaxtest COMMAND perl -cw ${CMAKE_BINARY_DIR}/onak-mail.pl)
 143 add_test(NAME sanitytests COMMAND ${CMAKE_SOURCE_DIR}/runtests)