configure.ac

   1 AC_PREREQ(2.50)
   2 AC_INIT([onak],[0.4.3],[noodles-onak@earth.li])
   3 AC_CONFIG_SRCDIR(onak.c)
   4 AC_CONFIG_HEADER(config.h)
   5
   6 AC_PROG_CC
   7 AC_PROG_CC_C99
   8
   9 AC_C_BIGENDIAN
  10
  11 m4_include([m4/ax_lib_nettle.m4])
  12
  13 AX_LIB_NETTLE(auto)
  14 AC_CHECK_HEADER([systemd/sd-daemon.h], [
  15         AC_CHECK_LIB([systemd-daemon], [sd_listen_fds],
  16                 [AC_DEFINE([HAVE_SYSTEMD], [1], [systemd-daemon is available])
  17                 AC_SUBST([SYSTEMD_LIBS], [-lsystemd-daemon])
  18         ])
  19 ])
  20
  21 dnl We should always have these backends available.
  22 backends="file fs keyd"
  23
  24 LIBCURL_CHECK_CONFIG(,,[have_libcurl="yes" backends="$backends hkp"],have_libcurl="no")
  25
  26 AC_CHECK_LIB(pq, PQsetdbLogin,[have_libpq="yes" backends="$backends pg"],have_libpq="no")
  27
  28 AC_CHECK_HEADER(db.h, have_db_h="yes", have_db_h="no")
  29 AC_MSG_CHECKING(for libdb version in db.h)
  30 printf "#include <db.h>\nDB_VERSION_MAJOR DB_VERSION_MINOR\n" >conftest.c
  31 set `eval $ac_cpp conftest.c | egrep '^ *[[0-9]] *'`; v="$1"; vv="$2"
  32 AC_MSG_RESULT($v.$vv)
  33 if test "$v" -ge 4; then
  34         for db in "db-$v.$vv" "db$v.$vv" "db-$v" "db$v" "db"; do
  35                 AC_MSG_CHECKING(for db_create in lib$db)
  36                 oldLIBS="$LIBS"
  37                 LIBS="$LIBS -l$db"
  38                 db4libs="-l$db"
  39                 AC_TRY_LINK([#include <db.h>], db_create(0, 0, 0),
  40                         have_libdb="yes", have_libdb="no")
  41                 AC_MSG_RESULT($have_libdb)
  42                 LIBS="$oldLIBS"
  43                 if test "$have_libdb" != "no"; then break; fi
  44         done
  45 fi
  46 if test "$have_libdb" = "yes" -a "$have_db_h" = "yes"; then
  47         AC_DEFINE(HAVE_LIBDB4, 1, [libdb found])
  48         backends="$backends db4"
  49 fi
  50
  51 AC_MSG_CHECKING(available backends)
  52 AC_MSG_RESULT($backends)
  53
  54 AC_ARG_ENABLE(backend,AC_HELP_STRING([--enable-backend=<backend>],[Choose the backend database to use. Defaults to dynamic.]), [], [enable_backend="dynamic"])
  55
  56 AC_ARG_ENABLE(keyd,AC_HELP_STRING([--enable-keyd],[Use keyd as the DB backend.]), [], [])
  57
  58 AC_MSG_CHECKING([which key database backend to use])
  59 AC_MSG_RESULT([$enable_backend])
  60 AC_CHECK_FILE([$srcdir/keydb_$enable_backend.c], ,AC_MSG_ERROR([non existent key database backend $enable_backend]))
  61
  62 if test "x$enable_backend" = "xdb4"
  63 then
  64         if test "$have_libdb" = "no" -o "$have_db_h" = "no"; then
  65                 AC_MSG_ERROR(libdb not found.)
  66         fi
  67         LIBS="$LIBS $db4libs"
  68 else if test "x$enable_backend" = "xpg"
  69 then
  70         if test "$have_libpq" = "no"; then
  71                 AC_MSG_ERROR(libpq not found.)
  72         fi
  73         LIBS="$LIBS -lpq"
  74 fi
  75 fi
  76
  77 dnl If we are explicitly told which backend to use, only build that one.
  78 if test "x$enable_backend" = "xdb4"
  79 then
  80         backend="$enable_backend"
  81 fi
  82
  83 AC_SUBST(DBTYPE, $enable_backend)
  84 AC_SUBST(DB4LIBS, $db4libs)
  85 AC_SUBST(KEYD, $enable_keyd)
  86 AC_SUBST(BACKENDS, $backends)
  87
  88 AC_CONFIG_FILES(Makefile)
  89
  90 AC_OUTPUT